Display Local and Remote Issue Links

import com.atlassian.jira.component.ComponentAccessor
import com.atlassian.jira.config.properties.APKeys
import com.atlassian.jira.issue.link.RemoteIssueLinkManager

// Get the components
def issueManager = ComponentAccessor.issueManager
def issueLinkManager = ComponentAccessor.issueLinkManager
def remoteIssueLinkManager = ComponentAccessor.getComponent(RemoteIssueLinkManager)

// Define the params to get an issue and filter the issue links by type
final issueKey = 'TEST-1'
final issueLinkTypeName = 'Blocks'

// Get the issue
def issue = issueManager.getIssueByCurrentKey(issueKey)

// Get the issue links to other issues
def issueLinks = issueLinkManager.getOutwardLinks(issue.id)
def filteredLinks = issueLinks.findAll { it.issueLinkType.name == issueLinkTypeName }

// Collect the HTML links pointing to the linked issues
def baseUrl = ComponentAccessor.applicationProperties.getString(APKeys.JIRA_BASEURL)
def linkedIssuesHtmlLinks = filteredLinks.collect { issueLink ->
    def issueUrl = "${baseUrl}/${issueLink.destinationObject.key}"
    "<a href='${issueUrl}'>${issueLink.destinationObject.key}</a>"
}

// Collect the HTML links pointing to the remote links
def remoteLinks = remoteIssueLinkManager.getRemoteIssueLinksForIssue(issue)
def remoteLinksHtml = remoteLinks.collect { remoteLink ->
    "<a href='${remoteLink.url}'>${remoteLink.title}</a>"
}

// Display the links
"""<p>Issue links:</p>
<ul>
    ${linkedIssuesHtmlLinks.collect { "<li>${it}</li>" }.join('\n')}
</ul>
<p>Remote links:</p>
<ul>
    ${remoteLinksHtml.collect { "<li>${it}</li>" }.join('\n')}
</ul>"""